firefly/Snakefile at master · ucvm/firefly · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
# ***********
# * FIREFLY *
# ***********


# **** Imports ****

import glob
from snakemake.utils import R, report


# **** Variables ****

configfile: "config.yaml"

VERSION='0.2.0'


samples = config["samples"]

# raw file list
glob_pat_r1 = expand("{dir}/{sample}_*R1*.fastq*", dir=config["read_directory"], sample=samples)
glob_pat_r2 = expand("{dir}/{sample}_*R2*.fastq*", dir=config["read_directory"], sample=samples)
raw_r1 = [glob.glob(x) for x in glob_pat_r1]
raw_r2 = [glob.glob(x) for x in glob_pat_r2]


# **** Rules ****

rule all:
    input:
        "results/taxonomy_out.rda",
        "multiqc_data/multiqc_fastqc.txt",
        "results/otus.tre"

rule qc:
    input:
        "multiqc_data/multiqc_fastqc.txt",
        expand("clipped/{sample}_R1.cut", sample = samples)

rule clip_primers:
    input:
        r1 = lambda wc: glob.glob("{dir}/{sample}_*R1*.fastq*".format(dir=config["read_directory"], sample=wc.sample)),
        r2 = lambda wc: glob.glob("{dir}/{sample}_*R2*.fastq*".format(dir=config["read_directory"], sample=wc.sample))
    output:
        r1 = "clipped/{sample}_R1.cut",
        r2 = "clipped/{sample}_R2.cut"
    log:
        "logs/{sample}.log"
    conda:
        "envs/quality.yaml"
    shell:
        """
	    cutadapt -g {config[fwd_primer]} -G {config[rev_primer]} \
            -a {config[rev_primer_rc]} -A {config[fwd_primer_rc]} \
            -m 50 -q {config[q_trim]} \
            -o {output.r1} -p {output.r2} {input.r1} {input.r2} >> {log}
        """

rule fastqc:
    input:
        raw_r1 + raw_r2
    output:
        touch("fastqc.done")
    threads:
        config["num_threads"]
    conda:
        "envs/quality.yaml"
    shell:
        "mkdir -p fastqc; fastqc -t {threads} -o fastqc {input}"

rule multiqc:
    input:
        "fastqc.done"
    output:
        "multiqc_data/multiqc_fastqc.txt"
    conda:
        "envs/quality.yaml"
    shell:
        "multiqc -f fastqc"

rule filter_and_trim:
    input:
        r1 = expand("clipped/{sample}_R1.cut", sample = samples),
        r2 = expand("clipped/{sample}_R2.cut", sample = samples)
    output:
        r1 = expand("filtered/{sample}_R1.fq", sample = samples),
        r2 = expand("filtered/{sample}_R2.fq", sample = samples),
        filt_out = "results/filtered.rds"
    threads:
        config["num_threads"]
    conda:
        "envs/dada2.yaml"
    script:
        "scripts/filter_and_trim.R"

rule learn_errors:
    input:
        r1 = rules.filter_and_trim.output.r1,
        r2 = rules.filter_and_trim.output.r2
    output:
        "results/error_rates.rda"
    threads:
        config["num_threads"]
    conda:
        "envs/dada2.yaml"
    script:
        "scripts/learn_errors.R"

rule infer_seqs:
    input:
        rules.learn_errors.output
    output:
        "results/merged.rds"
    threads:
        config["num_threads"]
    conda:
        "envs/dada2.yaml"
    script:
        "scripts/infer_seqs.R"

rule taxonomy:
    input:
        rules.infer_seqs.output
    output:
        taxonomy = "results/taxonomy_out.rda",
        otus = "results/otus.fasta"
    params:
        train_dir = config["train_dir"]
    threads:
        config["num_threads"]
    conda:
        "envs/dada2.yaml"
    script:
        "scripts/assign_taxonomy.R"

rule ssu_align:
    input:
        rules.taxonomy.output.otus
    output:
        "ssu_out/ssu_out.bacteria.stk"
    params:
        dir = "ssu_out"
    log:
        "logs/align.log"
    conda:
        "envs/align.yaml"
    shell:
        "ssu-align -f {input} {params.dir} &>> {log}"

rule ssu_mask:
    input:
        rules.ssu_align.output
    output:
        "ssu_out/ssu_out.bacteria.mask.afa"
    params:
        dir = "ssu_out"
    log:
        "logs/align.log"
    conda:
        "envs/align.yaml"
    shell:
        "ssu-mask --afa {params.dir} &>> {log}"

rule tree:
    input:
        rules.ssu_mask.output
    output:
        "results/otus.tre"
    log:
        "logs/tree.log"
    conda:
        "envs/align.yaml"
    shell:
        "FastTree -nt {input} >{output} 2> {log}"