Investigate OpenMcdf 3

[rmcanany]

@farfilli

It's a start, I guess...

.

.

[rmcanany]

By the way, unless my guy says the fix for the 2.4.0/2.4.1 issue didn't work, I'm not convinced this is urgent. As far as I know it's working fine otherwise. Thoughts?

[farfilli]

Well, in my opinion moving to the current version would be a benefit in the long term. We don't have much development to do with it therefore I agree it's not urgent.

To the other side, I guess it will not be that big work to do, in fact we collect properties and then handle them outside OpenMcdf. Solid Edge Explorer just open the byte stream and would be even faster to update.

About Solid Edge Explorer, during one of the latest commits I have used your code to grab all the properties, but I messed it a bit to remove the localisation of property names. When you have time I would like you to take a look and think about a way to easily unify/maintain the code. Or another option to simplify it for SEE

[rmcanany]

Got a note from my guy this morning. The latest fix did the trick.

I agree that upgrading makes sense for the long term, and doesn't look like a lot of work. As I get time, I'll continue testing to verify it'll do what we need. I wouldn't mind seeing OpenMcdf.Ole lose the Experimental label; that kinda makes me nervous.

I can study the code with an eye for better integration. SEE is awesome, by the way.

[farfilli]

With version 3.x I would try to improve the properties retriaval performance.

At the moment, the more properties are shown in the file list columns the more times is needed and if the list is huge it has an impact.

[rmcanany]

Seems like a candidate for multi-threading. I've never done it, have you?

[farfilli]

OpenMcdf 3.x should be congenitally faster, would be first to compare

[farfilli]

Multi-threading would be an option for not blocking the user, but if you want to sort by a column, you will need all the data.
Another option would be to load column values only when the item became visible, but I had problems with the method to identify the row position.

In the end, let's compare times from 2.4.1 to 3.x, then we can decide what to do.

[rmcanany]

Sounds good. I'm going to play with v3 this week. I'll let you know what I find.

[farfilli]

Let me know if you need a v3 of SEE, should be very few lines of code to change

[rmcanany]

I should be about ready for SEE using v3. In my test project, most of the functionality (needed for Housekeeper) is working.

The API has changed a bit. I made some functions to help me with the transition. Not sure you need any of them, but they are copied below just in case. Note that someStream.GetData is gone in v3. There is a method called GetData that shows a way to do that now.

    Private Class SSTools

        Public Shared Function GetStorage(
            _cf As OpenMcdf.Storage,
            StorageName As String
            ) As OpenMcdf.Storage

            Dim tmpStorage As OpenMcdf.Storage = Nothing
            Dim tmpList As List(Of OpenMcdf.Storage) = GetStorages(_cf, StorageName)
            If tmpList IsNot Nothing AndAlso tmpList.Count > 0 Then
                tmpStorage = tmpList(0)
            End If
            Return tmpStorage
        End Function

        Public Shared Function GetStream(
            _cf As OpenMcdf.Storage,
            StreamName As String
            ) As OpenMcdf.CfbStream

            Dim tmpStream As OpenMcdf.CfbStream = Nothing
            Dim tmpList As List(Of OpenMcdf.CfbStream) = GetStreams(_cf, StreamName)
            If tmpList IsNot Nothing AndAlso tmpList.Count > 0 Then
                tmpStream = tmpList(0)
            End If
            Return tmpStream
        End Function

        Public Shared Function GetStorages(
            _cf As OpenMcdf.Storage,
            NameWildcard As String
            ) As List(Of OpenMcdf.Storage)

            Dim StorageList As List(Of OpenMcdf.Storage) = Nothing
            Dim tmpList As List(Of Object)
            tmpList = VisitEntries(_cf, OpenMcdf.EntryType.Storage, NameWildcard)

            If tmpList IsNot Nothing Then
                StorageList = New List(Of OpenMcdf.Storage)
                For Each Item As Object In tmpList
                    StorageList.Add(CType(Item, OpenMcdf.Storage))
                Next
            End If

            Return StorageList
        End Function

        Public Shared Function GetStreams(
            _cf As OpenMcdf.Storage,
            NameWildcard As String
            ) As List(Of OpenMcdf.CfbStream)

            Dim StreamList As List(Of OpenMcdf.CfbStream) = Nothing
            Dim tmpList As List(Of Object)
            tmpList = VisitEntries(_cf, OpenMcdf.EntryType.Stream, NameWildcard)

            If tmpList IsNot Nothing Then
                StreamList = New List(Of OpenMcdf.CfbStream)
                For Each Item As Object In tmpList
                    StreamList.Add(CType(Item, OpenMcdf.CfbStream))
                Next
            End If

            Return StreamList
        End Function

        Private Shared Function VisitEntries(
            _cf As OpenMcdf.Storage,
            EntryType As OpenMcdf.EntryType,
            NameWildcard As String
            ) As List(Of Object)

            Dim tmpList As List(Of Object) = Nothing

            Dim entries As IEnumerable(Of OpenMcdf.EntryInfo) = _cf.EnumerateEntries
            For Each EntryInfo As OpenMcdf.EntryInfo In entries
                If EntryInfo.Type = EntryType Then
                    If EntryInfo.Name Like NameWildcard Then
                        If tmpList Is Nothing Then tmpList = New List(Of Object)  ' Initialize only when we have a first match.
                        Select Case EntryType
                            Case OpenMcdf.EntryType.Storage
                                tmpList.Add(_cf.OpenStorage(EntryInfo.Name))
                            Case OpenMcdf.EntryType.Stream
                                tmpList.Add(_cf.OpenStream(EntryInfo.Name))
                        End Select
                    End If
                End If
            Next

            Return tmpList
        End Function

        Public Shared Function GetData(
            _cf As OpenMcdf.Storage,
            StreamName As String
            ) As Byte()

            Dim tmpStream As OpenMcdf.CfbStream = GetStream(_cf, StreamName)

            If tmpStream IsNot Nothing AndAlso tmpStream.Length > 0 Then
                Dim Buffer(CInt(tmpStream.Length) - 1) As Byte
                tmpStream.Read(Buffer, 0, CInt(tmpStream.Length))
                Return Buffer
            Else
                Return Nothing
            End If

        End Function

        Public Shared Function IsFileEmpty(
            cf As OpenMcdf.Storage,
            Filename As String
            ) As Boolean

            Dim IsEmpty As Boolean = True

            Dim DocType As String = IO.Path.GetExtension(Filename).Replace(".", "")
            Select Case DocType
                Case "par", "psm"
                    Dim ParasolidStorage As OpenMcdf.Storage = GetStorage(cf, "PARASOLID")
                    If ParasolidStorage IsNot Nothing Then
                        Dim ParasolidStreams As List(Of OpenMcdf.CfbStream) = GetStreams(ParasolidStorage, "*")
                        If ParasolidStreams IsNot Nothing AndAlso ParasolidStreams.Count > 0 Then
                            IsEmpty = False
                        End If
                    End If

                Case "asm", "dft"
                    'If Me.LinkNames IsNot Nothing Then
                    '    IsEmpty = (Me.LinkNames.Items.Count = 0) And (Me.LinkNames.BadLinks.Count = 0)
                    'Else
                    '    Dim tmpLinkManagmentOrder As List(Of String) = {"CONTAINER", "RELATIVE", "ABSOLUTE"}.ToList
                    '    Dim tmpLinkNames = New LinkFullNames(Me.cf, IsFOA(), tmpLinkManagmentOrder, Me.FullName)
                    '    IsEmpty = (tmpLinkNames.Items.Count = 0) And (tmpLinkNames.BadLinks.Count = 0)
                    'End If
            End Select

            Return IsEmpty
        End Function

        Public Shared Function ContainsStorage(_cf As OpenMcdf.Storage, StorageName As String) As Boolean
            Return GetStorage(_cf, StorageName) IsNot Nothing
        End Function

        Public Shared Function ContainsStream(_cf As OpenMcdf.Storage, StreamName As String) As Boolean
            Return GetStream(_cf, StreamName) IsNot Nothing
        End Function

        'Private Shared Function StorageContains(
        '    Storage As OpenMcdf.Storage,
        '    Name As String,
        '    EntryType As OpenMcdf.EntryType
        '    ) As Boolean

        '    Dim Success As Boolean = False
        '    If Storage.ContainsEntry(Name) Then
        '        Dim EntryInfo As OpenMcdf.EntryInfo = Nothing
        '        Storage.TryGetEntryInfo(Name, EntryInfo)
        '        If Not EntryInfo = Nothing AndAlso EntryInfo.Type = EntryType Then
        '            Success = True
        '        End If
        '    End If
        '    Return Success
        'End Function

    End Class

[farfilli]

Updated SEE to use OpenMcdf 3.1.3

I have temporarily disabled properties retrieval and integrated your utilities.
Code is a bit of a mess, but it's working. I should start to clean it up.